init

2026-02-12 18:53:24 +00:00 · 2026-02-12 18:53:24 +00:00 · a07bd5fd9b
commit a07bd5fd9b
66 changed files with 6115 additions and 0 deletions
--- a/hosts/nixarawrui/modules/amdgpu-ignore-ctx-privileges.nix
+++ b/hosts/nixarawrui/modules/amdgpu-ignore-ctx-privileges.nix
@ -0,0 +1,32 @@
+{
+  pkgs,
+  lib,
+  config,
+  ...
+}: let
+  enabled = config.boot.kernelPatchesOptions.amd-ignore-ctx-privileges;
+in {
+  options = {
+    boot.kernelPatchesOptions.amd-ignore-ctx-privileges =
+      lib.mkEnableOption "amd-ignore-ctx-privileges";
+  };
+
+  config = lib.mkIf enabled {
+    nixpkgs.overlays = [
+      (self: super: {
+        amdgpu-ignore-ctx-privileges = super.fetchpatch {
+          name = "cap_sys_nice_begone.patch";
+          url = "https://github.com/Frogging-Family/community-patches/raw/master/linux61-tkg/cap_sys_nice_begone.mypatch";
+          hash = "sha256-Y3a0+x2xvHsfLax/uwycdJf3xLxvVfkfDVqjkxNaYEo=";
+        };
+      })
+    ];
+
+    boot.kernelPatches = [
+      {
+        name = "amdgpu-ignore-ctx-privileges";
+        patch = pkgs.amdgpu-ignore-ctx-privileges;
+      }
+    ];
+  };
+}