add nix compatible build environment

flake.nix

@@ -0,0 +1,68 @@
+{
+  description = "ooni's cool website ohmahhhgawwww";
+
+  inputs = {
+    systems.url = "github:nix-systems/default";
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+    ...
+  } @ inputs: let
+    systems = import inputs.systems;
+
+    mkPkgs = pkgs: system:
+      import pkgs {
+        inherit system;
+        allowUnfree = false;
+        allowBroken = false;
+        overlays = builtins.attrValues self.overlays or {};
+      };
+
+    forAllSystems = f:
+      nixpkgs.lib.genAttrs systems (system:
+        f rec {
+          inherit system;
+          inherit (pkgs) lib;
+          pkgs = mkPkgs nixpkgs system;
+        });
+  in {
+    overlays.default = self: super: {
+      wa2k-website = super.stdenv.mkDerivation {
+        name = "wa2k.com";
+        src = ./.;
+
+        installPhase = ''
+          mkdir -p $out
+          cp -r www $out/
+        '';
+      };
+    };
+
+    nixosModules = rec {
+      default = wa2k;
+      wa2k = import ./nixos;
+    };
+
+    checks = self.packages;
+    packages = forAllSystems ({pkgs, ...}: rec {
+      inherit (pkgs) wa2k-website;
+      default = wa2k-website;
+    });
+
+    devShells = forAllSystems ({pkgs, ...}: let
+      devPackages = with pkgs; [
+        # dev local server
+        simple-http-server
+      ];
+    in {
+      default = pkgs.mkShell {
+        name = "wa2k.com";
+        shell = "${pkgs.bash}/bin/bash";
+        packages = devPackages;
+      };
+    });
+  };
+}