brownian motion experiments

www/shaders/fbm.glsl

@@ -0,0 +1,97 @@
+// Author @patriciogv - 2015
+// http://patriciogonzalezvivo.com
+
+#ifdef GL_ES
+precision mediump float;
+#endif
+
+uniform vec2 u_resolution;
+uniform vec2 u_mouse;
+uniform float u_time;
+
+float random (in vec2 _st) {
+    return fract(sin(dot(_st.xy,
+                         vec2(12.9898,78.233)))*
+        43758.5453123);
+}
+
+// Based on Morgan McGuire @morgan3d
+// https://www.shadertoy.com/view/4dS3Wd
+float noise (in vec2 _st) {
+    vec2 i = floor(_st);
+    vec2 f = fract(_st);
+
+    // Four corners in 2D of a tile
+    float a = random(i);
+    float b = random(i + vec2(1.0, 0.0));
+    float c = random(i + vec2(0.0, 1.0));
+    float d = random(i + vec2(1.0, 1.0));
+
+    vec2 u = f * f * (3.0 - 2.0 * f);
+
+    return mix(a, b, u.x) +
+            (c - a)* u.y * (1.0 - u.x) +
+            (d - b) * u.x * u.y;
+}
+
+#define NUM_OCTAVES 100
+// Brightness (0.0 - 1.0)
+#define BRIGHTNESS 0.55
+#define LACUNARITY 2.0
+#define GAIN 0.5
+#define SHIFT 100.0
+
+// VAR_THETA defines whether to compute
+// sin/cos values at runtime or 
+#define VAR_THETA 0
+#define THETA 0.5
+#if (VAR_THETA == 1)
+#endif
+
+float fbm ( in vec2 _st) {
+    float v = 0.0;
+    float a = BRIGHTNESS;
+    // Rotate to reduce axial bias
+    mat2 T = LACUNARITY * mat2(cos(THETA), sin(THETA), 
+                               -sin(THETA), cos(THETA));
+    for (int i = 0; i < NUM_OCTAVES; ++i) {
+        _st = T * _st + SHIFT;
+        v += noise(_st) * a;
+        a *= GAIN;
+    }
+    return v;
+}
+
+#define SCALE 3.
+
+void main() {
+    vec2 st = gl_FragCoord.xy/u_resolution.xy*SCALE;
+    // st += st * abs(sin(u_time*0.1)*3.0);
+
+    vec2 q = vec2(
+        fbm( st + 0.*u_time),
+    	fbm( st + vec2(1.0))
+    );
+
+    vec2 r = vec2(
+    	fbm( st + 1.0*q + vec2(1.7,9.2)+ 0.15*u_time ),
+    	fbm( st + 1.0*q + vec2(8.3,2.8)+ 0.126*u_time)
+    );
+
+    float f = fbm(st+r);
+
+    vec3 color = mix(vec3(0.101961,0.619608,0.666667),
+                vec3(0.666667,0.666667,0.498039),
+                clamp((f*f)*4.0,0.0,1.0));
+
+    color = mix(color,
+                vec3(0,0,0.164706),
+                clamp(length(q),0.0,1.0));
+
+    color = mix(color,
+                vec3(0.666667,1,1),
+                clamp(length(r.x),0.0,1.0));
+
+    gl_FragColor = vec4((f*f*f+.6*f*f+.5*f)*color,1.);
+}
+